6acaab0ffa
* add focusController class * add more key handlers * add focus navigation to qml * fixed language selector * add reverse focus change to FocusController * add default focus item * update transitions * update pages * add ListViewFocusController * fix ListView navigation * update CardType for using with focus navigation * remove useless key navigation * remove useless slots, logs, Drawer open and close * fix reverse focus move on listView * fix drawer radio buttons selection * fix drawer layout and focus move * fix PageSetupWizardProtocolSettings focus move * fix back navigation on default focus item * fix crashes after ListView navigation * fix protocol settings focus move * fix focus on users on page share * clean up page share * fix server rename * fix page share default server selection * refactor about page for correct focus move * fix focus move on list views with header and-or footer * minor fixes * fix server list back button handler * fix spawn signals on switch * fix share details drawer * fix drawer open close usage * refactor listViewFocusController * refactor focusController to make the logic more straightforward * fix focus on notification * update config page for scrolling with tab * fix crash on return with esc key * fix focus navigation in dynamic delegate of list view * fix focus move on qr code on share page * refactor page logging settings for focus navigation * update popup * Bump version * Add mandatory requirement for android.software.leanback. * Fix importing files on TVs * fix: add separate method for reading files to fix file reading on Android TV * fix(android): add CHANGE_NETWORK_STATE permission for all Android versions * Fix connection check for AWG/WG * chore: minor fixes (#1235) * fix: add a workaround to open files on Android TV due to lack of SAF * fix: change the banner format for TV * refactor: make TvFilePicker activity more sustainable * fix: add the touch emulation method for Android TV * fix: null uri processing * fix: add the touch emulation method for Android TV * fix: hide UI elements that use file saving * chore: bump version code * add `ScrollBarType` * update initial config page * refactor credentials setup page to handle the focus navigation * add `setDelegateIndex` method to `listViewFocusController` * fix focus behavior on new page/popup * make minor fixes and clean up * fix: get rid of the assign function call * Scrollbar is on if the content is larger than a screen * Fix selection in language change list * Update select language list * update logging settings page * fix checked item in lists * fix split tunneling settings * make unchangable properties readonly * refactor SwitcherType * fix hide/unhide password * `PageShare` readonly properties * Fix list view focus moving on `PageShare` * remove manual focus control on `PageShare` * format `ListViewFocusController` * format `FocusController` * add `focusControl` with utility functions for focus control * refactor `listViewFocusController` acoording to `focusControl` * refactor `focusConroller` according to `focusControl` * add `printSectionName` method to `listViewController` * remove arrow from `Close application` item * fix focus movement in `ServersListView` * `Restore from backup` is visible only on start screen * `I have nothing` is visible only on start screen * fix back button on `SelectLanguageDrawer` * rename `focusControl` to `qmlUtils` * fix `CMakeLists.txt` * fix `ScrollBarType` * fix `PageSetupWizardApiServicesList` * fix focus movement on dynamic delegates in listView * refactor `PageSetupWizardProtocols` * remove comments and clean up * fix `ListViewWithLabelsType` * fix `PageProtocolCloakSettings` * fix `PageSettingsAppSplitTunneling` * fix `PageDevMenu` * remove debug output from `FocusController` * remove debug output from `ListViewFocusController` * remove debug output from `focusControl` * `focusControl` => `FocusControl` --------- Co-authored-by: albexk <albexk@proton.me> Co-authored-by: Nethius <nethiuswork@gmail.com>
419 lines
16 KiB
QML
419 lines
16 KiB
QML
import QtQuick
|
|
import QtQuick.Controls
|
|
import QtQuick.Layouts
|
|
|
|
import SortFilterProxyModel 0.2
|
|
|
|
import PageEnum 1.0
|
|
import ContainerEnum 1.0
|
|
import Style 1.0
|
|
|
|
import "./"
|
|
import "../Controls2"
|
|
import "../Controls2/TextTypes"
|
|
import "../Config"
|
|
import "../Components"
|
|
|
|
PageType {
|
|
id: root
|
|
|
|
ColumnLayout {
|
|
id: backButtonLayout
|
|
|
|
anchors.top: parent.top
|
|
anchors.left: parent.left
|
|
anchors.right: parent.right
|
|
|
|
anchors.topMargin: 20
|
|
|
|
BackButtonType {
|
|
id: backButton
|
|
}
|
|
}
|
|
|
|
FlickableType {
|
|
id: fl
|
|
anchors.top: backButtonLayout.bottom
|
|
anchors.bottom: parent.bottom
|
|
contentHeight: content.implicitHeight
|
|
|
|
Column {
|
|
id: content
|
|
|
|
anchors.top: parent.top
|
|
anchors.left: parent.left
|
|
anchors.right: parent.right
|
|
|
|
enabled: ServersModel.isProcessedServerHasWriteAccess()
|
|
|
|
ListView {
|
|
id: listview
|
|
|
|
width: parent.width
|
|
height: listview.contentItem.height
|
|
|
|
clip: true
|
|
interactive: false
|
|
|
|
model: OpenVpnConfigModel
|
|
|
|
delegate: Item {
|
|
implicitWidth: listview.width
|
|
implicitHeight: col.implicitHeight
|
|
|
|
property alias vpnAddressSubnetTextField: vpnAddressSubnetTextField
|
|
|
|
ColumnLayout {
|
|
id: col
|
|
|
|
anchors.top: parent.top
|
|
anchors.left: parent.left
|
|
anchors.right: parent.right
|
|
|
|
anchors.leftMargin: 16
|
|
anchors.rightMargin: 16
|
|
|
|
spacing: 0
|
|
|
|
HeaderType {
|
|
Layout.fillWidth: true
|
|
|
|
headerText: qsTr("OpenVPN settings")
|
|
}
|
|
|
|
TextFieldWithHeaderType {
|
|
id: vpnAddressSubnetTextField
|
|
|
|
Layout.fillWidth: true
|
|
Layout.topMargin: 32
|
|
|
|
headerText: qsTr("VPN address subnet")
|
|
textFieldText: subnetAddress
|
|
|
|
parentFlickable: fl
|
|
|
|
textField.onEditingFinished: {
|
|
if (textFieldText !== subnetAddress) {
|
|
subnetAddress = textFieldText
|
|
}
|
|
}
|
|
}
|
|
|
|
ParagraphTextType {
|
|
Layout.fillWidth: true
|
|
Layout.topMargin: 32
|
|
|
|
text: qsTr("Network protocol")
|
|
}
|
|
|
|
TransportProtoSelector {
|
|
id: transportProtoSelector
|
|
Layout.fillWidth: true
|
|
Layout.topMargin: 16
|
|
rootWidth: root.width
|
|
|
|
enabled: isTransportProtoEditable
|
|
|
|
currentIndex: {
|
|
return transportProto === "tcp" ? 1 : 0
|
|
}
|
|
|
|
onCurrentIndexChanged: {
|
|
if (transportProto === "tcp" && currentIndex === 0) {
|
|
transportProto = "udp"
|
|
} else if (transportProto === "udp" && currentIndex === 1) {
|
|
transportProto = "tcp"
|
|
}
|
|
}
|
|
}
|
|
|
|
TextFieldWithHeaderType {
|
|
id: portTextField
|
|
|
|
Layout.fillWidth: true
|
|
Layout.topMargin: 40
|
|
parentFlickable: fl
|
|
|
|
enabled: isPortEditable
|
|
|
|
headerText: qsTr("Port")
|
|
textFieldText: port
|
|
textField.maximumLength: 5
|
|
textField.validator: IntValidator { bottom: 1; top: 65535 }
|
|
|
|
textField.onEditingFinished: {
|
|
if (textFieldText !== port) {
|
|
port = textFieldText
|
|
}
|
|
}
|
|
}
|
|
|
|
SwitcherType {
|
|
id: autoNegotiateEncryprionSwitcher
|
|
|
|
Layout.fillWidth: true
|
|
Layout.topMargin: 24
|
|
parentFlickable: fl
|
|
|
|
text: qsTr("Auto-negotiate encryption")
|
|
checked: autoNegotiateEncryprion
|
|
|
|
onCheckedChanged: {
|
|
if (checked !== autoNegotiateEncryprion) {
|
|
autoNegotiateEncryprion = checked
|
|
}
|
|
}
|
|
}
|
|
|
|
DropDownType {
|
|
id: hashDropDown
|
|
Layout.fillWidth: true
|
|
Layout.topMargin: 20
|
|
|
|
enabled: !autoNegotiateEncryprionSwitcher.checked
|
|
|
|
descriptionText: qsTr("Hash")
|
|
headerText: qsTr("Hash")
|
|
|
|
drawerParent: root
|
|
parentFlickable: fl
|
|
|
|
listView: ListViewWithRadioButtonType {
|
|
id: hashListView
|
|
|
|
rootWidth: root.width
|
|
|
|
model: ListModel {
|
|
ListElement { name : qsTr("SHA512") }
|
|
ListElement { name : qsTr("SHA384") }
|
|
ListElement { name : qsTr("SHA256") }
|
|
ListElement { name : qsTr("SHA3-512") }
|
|
ListElement { name : qsTr("SHA3-384") }
|
|
ListElement { name : qsTr("SHA3-256") }
|
|
ListElement { name : qsTr("whirlpool") }
|
|
ListElement { name : qsTr("BLAKE2b512") }
|
|
ListElement { name : qsTr("BLAKE2s256") }
|
|
ListElement { name : qsTr("SHA1") }
|
|
}
|
|
|
|
clickedFunction: function() {
|
|
hashDropDown.text = selectedText
|
|
hash = hashDropDown.text
|
|
hashDropDown.closeTriggered()
|
|
}
|
|
|
|
Component.onCompleted: {
|
|
hashDropDown.text = hash
|
|
|
|
for (var i = 0; i < hashListView.model.count; i++) {
|
|
if (hashListView.model.get(i).name === hashDropDown.text) {
|
|
currentIndex = i
|
|
}
|
|
}
|
|
}
|
|
}
|
|
}
|
|
|
|
DropDownType {
|
|
id: cipherDropDown
|
|
Layout.fillWidth: true
|
|
Layout.topMargin: 16
|
|
|
|
enabled: !autoNegotiateEncryprionSwitcher.checked
|
|
|
|
descriptionText: qsTr("Cipher")
|
|
headerText: qsTr("Cipher")
|
|
|
|
drawerParent: root
|
|
parentFlickable: fl
|
|
|
|
listView: ListViewWithRadioButtonType {
|
|
id: cipherListView
|
|
|
|
rootWidth: root.width
|
|
|
|
model: ListModel {
|
|
ListElement { name : qsTr("AES-256-GCM") }
|
|
ListElement { name : qsTr("AES-192-GCM") }
|
|
ListElement { name : qsTr("AES-128-GCM") }
|
|
ListElement { name : qsTr("AES-256-CBC") }
|
|
ListElement { name : qsTr("AES-192-CBC") }
|
|
ListElement { name : qsTr("AES-128-CBC") }
|
|
ListElement { name : qsTr("ChaCha20-Poly1305") }
|
|
ListElement { name : qsTr("ARIA-256-CBC") }
|
|
ListElement { name : qsTr("CAMELLIA-256-CBC") }
|
|
ListElement { name : qsTr("none") }
|
|
}
|
|
|
|
clickedFunction: function() {
|
|
cipherDropDown.text = selectedText
|
|
cipher = cipherDropDown.text
|
|
cipherDropDown.closeTriggered()
|
|
}
|
|
|
|
Component.onCompleted: {
|
|
cipherDropDown.text = cipher
|
|
|
|
for (var i = 0; i < cipherListView.model.count; i++) {
|
|
if (cipherListView.model.get(i).name === cipherDropDown.text) {
|
|
currentIndex = i
|
|
}
|
|
}
|
|
}
|
|
}
|
|
}
|
|
|
|
Rectangle {
|
|
id: contentRect
|
|
Layout.fillWidth: true
|
|
Layout.topMargin: 32
|
|
Layout.preferredHeight: checkboxLayout.implicitHeight
|
|
color: AmneziaStyle.color.onyxBlack
|
|
radius: 16
|
|
|
|
Connections {
|
|
target: tlsAuthCheckBox
|
|
enabled: !GC.isMobile()
|
|
|
|
function onFocusChanged() {
|
|
if (tlsAuthCheckBox.activeFocus) {
|
|
fl.ensureVisible(contentRect)
|
|
}
|
|
}
|
|
}
|
|
|
|
ColumnLayout {
|
|
id: checkboxLayout
|
|
|
|
anchors.fill: parent
|
|
CheckBoxType {
|
|
id: tlsAuthCheckBox
|
|
Layout.fillWidth: true
|
|
|
|
text: qsTr("TLS auth")
|
|
checked: tlsAuth
|
|
|
|
onCheckedChanged: {
|
|
if (checked !== tlsAuth) {
|
|
console.log("tlsAuth changed to: " + checked)
|
|
tlsAuth = checked
|
|
}
|
|
}
|
|
}
|
|
|
|
DividerType {}
|
|
|
|
CheckBoxType {
|
|
id: blockDnsCheckBox
|
|
Layout.fillWidth: true
|
|
|
|
text: qsTr("Block DNS requests outside of VPN")
|
|
checked: blockDns
|
|
|
|
onCheckedChanged: {
|
|
if (checked !== blockDns) {
|
|
blockDns = checked
|
|
}
|
|
}
|
|
}
|
|
}
|
|
}
|
|
|
|
SwitcherType {
|
|
id: additionalClientCommandsSwitcher
|
|
Layout.fillWidth: true
|
|
Layout.topMargin: 32
|
|
parentFlickable: fl
|
|
|
|
checked: additionalClientCommands !== ""
|
|
|
|
text: qsTr("Additional client configuration commands")
|
|
|
|
onCheckedChanged: {
|
|
if (!checked) {
|
|
additionalClientCommands = ""
|
|
}
|
|
}
|
|
}
|
|
|
|
TextAreaType {
|
|
id: additionalClientCommandsTextArea
|
|
Layout.fillWidth: true
|
|
Layout.topMargin: 16
|
|
|
|
visible: additionalClientCommandsSwitcher.checked
|
|
|
|
parentFlickable: fl
|
|
|
|
textAreaText: additionalClientCommands
|
|
placeholderText: qsTr("Commands:")
|
|
|
|
textArea.onEditingFinished: {
|
|
if (additionalClientCommands !== textAreaText) {
|
|
additionalClientCommands = textAreaText
|
|
}
|
|
}
|
|
}
|
|
|
|
SwitcherType {
|
|
id: additionalServerCommandsSwitcher
|
|
Layout.fillWidth: true
|
|
Layout.topMargin: 16
|
|
parentFlickable: fl
|
|
|
|
checked: additionalServerCommands !== ""
|
|
|
|
text: qsTr("Additional server configuration commands")
|
|
|
|
onCheckedChanged: {
|
|
if (!checked) {
|
|
additionalServerCommands = ""
|
|
}
|
|
}
|
|
}
|
|
|
|
TextAreaType {
|
|
id: additionalServerCommandsTextArea
|
|
Layout.fillWidth: true
|
|
Layout.topMargin: 16
|
|
|
|
visible: additionalServerCommandsSwitcher.checked
|
|
|
|
textAreaText: additionalServerCommands
|
|
placeholderText: qsTr("Commands:")
|
|
parentFlickable: fl
|
|
textArea.onEditingFinished: {
|
|
if (additionalServerCommands !== textAreaText) {
|
|
additionalServerCommands = textAreaText
|
|
}
|
|
}
|
|
}
|
|
|
|
BasicButtonType {
|
|
id: saveRestartButton
|
|
|
|
Layout.fillWidth: true
|
|
Layout.topMargin: 24
|
|
Layout.bottomMargin: 24
|
|
|
|
text: qsTr("Save")
|
|
parentFlickable: fl
|
|
|
|
clickedFunc: function() {
|
|
forceActiveFocus()
|
|
|
|
if (ConnectionController.isConnected && ServersModel.getDefaultServerData("defaultContainer") === ContainersModel.getProcessedContainerIndex()) {
|
|
PageController.showNotificationMessage(qsTr("Unable change settings while there is an active connection"))
|
|
return
|
|
}
|
|
|
|
PageController.goToPage(PageEnum.PageSetupWizardInstalling);
|
|
InstallController.updateContainer(OpenVpnConfigModel.getConfig())
|
|
}
|
|
}
|
|
}
|
|
}
|
|
}
|
|
}
|
|
}
|
|
}
|